mason::component::moose(3pm) [debian man page]

Mason::Component::Moose(3pm)				User Contributed Perl Documentation			      Mason::Component::Moose(3pm)

NAME

       Mason::Component::Moose - Moose policies and exports for Mason components

DESCRIPTION

       This module is automatically included in each generated Mason component class, and is equivalent to

	   use CLASS;
	   use Moose;
	   use MooseX::HasDefaults::RW;
	   use Method::Signatures::Simple;

OVERRIDING

       To override the default behavior, subclass this class and specify it as "base_component_moose_class" to Mason::Interp.

       For example, to use MooseX::StrictConstructor in every component:

	   package My::Mason::Component::Moose;
	   use Moose::Exporter;
	   use MooseX::StrictConstructor ();
	   use base qw(Mason::Component::Moose);

	   sub init_meta {
	       my $class = shift;
	       $class->SUPER::init_meta(@_);
	       MooseX::StrictConstructor->init_meta(@_);
	   }

	   ...

	   my $interp = Mason::Interp->new(..., base_component_moose_class => 'My::Mason::Component::Moose');

SEE ALSO

       Mason

AUTHOR

       Jonathan Swartz <swartz@pobox.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2011 by Jonathan Swartz.

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.14.2							    2012-05-02					      Mason::Component::Moose(3pm)

Poet::Manual::Subclassing(3pm)				User Contributed Perl Documentation			    Poet::Manual::Subclassing(3pm)

NAME

       Poet::Manual::Subclassing - Customizing Poet with subclasses

DESCRIPTION

       You can subclass the following Poet classes for your application:

	   Poet::Cache
	   Poet::Conf
	   Poet::Log
	   Poet::Mason
	   Poet::Import

       and arrange things so that Poet always uses your subclass instead of its default class.

       Place Poet subclasses under "lib/MyApp/Class.pm" in your environment, where "MyApp" is your app name and "Class" is the class you are
       subclassing minus the "Poet" prefix. A few of these subclasses are generated for you by "poet new".

       For example, to subclass "Poet::Cache":

	   package MyApp::Cache;
	   use Poet::Moose;
	   extends 'Poet::Cache';

	   # put your modifications here

	   1;

       (Note: Poet::Moose is Moose plus a few Poet standards. You could also use plain "Moose" here.)

       Poet will automatically detect, load and use any such subclasses. Internally it uses the app_class environment method whenever it needs a
       classname, e.g.

	   # Do something with MyApp::Cache or Poet::Cache
	   $poet->app_class('Cache')->...

   Subclassing Mason
       As long as you have even a bare-bones "Poet::Mason" subclass, e.g.

	   package MyApp::Mason;
	   use Poet::Moose;
	   extends 'Poet::Mason';

	   1;

       then your Mason subclasses will be autodetected as well, e.g.

	   package MyApp::Mason::Interp;
	   use Moose;
	   extends 'Mason::Interp';
	   # put your modifications here
	   1;

       "poet new" will create the bare-bones subclass for you; it is otherwise harmless.

       See Mason::Manual::Subclasses for more information.

EXAMPLES

   Use INI instead of YAML for config files
	   package MyApp::Conf;
	   use Config::INI;
	   use Moose;
	   extends 'Poet::Conf';

	   override 'read_conf_file' => sub {
	       my ($self, $file) = @_;
	       return Config::INI::Reader->read_file($file);
	   };

   Perform tasks before and after each Mason request
	   package MyApp::Mason::Request;
	   use Moose;
	   extends 'Mason::Request';

	   override 'run' => sub {
	       my $self = shift;

	       # Perform tasks before request
	       my $result = super();
	       # Perform tasks after request

	       return $result;
	   };

   Add Perl code to the top of every compiled component
	   package MyApp::Mason::Compilation;
	   use Moose;
	   extends 'Mason::Compilation';

	   override 'output_class_header' => sub {
		return join("
", super(), 'use Foo;', 'use Bar qw(baz);');
	   };

   Use Log::Dispatch instead of Log4perl for logging
	   package MyApp::Log;
	   use Log::Any::Adapter;
	   use Log::Dispatch;
	   use Moose;
	   extends 'Poet::Log';

	   override 'initialize_logging' => sub {
	       my $log = Log::Dispatch->new( ... );
	       Log::Any::Adapter->set('Dispatch', dispatcher => $log);
	   };

   Add your own $dbh quick var
	   package MyApp::Import
	   use DBI;
	   use Poet::Moose;
	   extends 'Poet::Import';

	   method provide_dbh ($caller, $poet) {
	       $dbh = DBI->connect(...);
	   }

SEE ALSO

       Poet

AUTHOR

       Jonathan Swartz <swartz@pobox.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2012 by Jonathan Swartz.

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.14.2							    2012-06-05					    Poet::Manual::Subclassing(3pm)