plack::test(3pm) [debian man page]

Plack::Test(3pm)					User Contributed Perl Documentation					  Plack::Test(3pm)

NAME

       Plack::Test - Test PSGI applications with various backends

SYNOPSIS

	 use Plack::Test;

	 # named params
	 test_psgi
	     app => sub {
		 my $env = shift;
		 return [ 200, [ 'Content-Type' => 'text/plain' ], [ "Hello World" ] ],
	     },
	     client => sub {
		 my $cb  = shift;
		 my $req = HTTP::Request->new(GET => "http://localhost/hello");
		 my $res = $cb->($req);
		 like $res->content, qr/Hello World/;
	     };

	  use HTTP::Request::Common;

	  # positional params (app, client)
	  my $app = sub { return [ 200, [], [ "Hello "] ] };
	  test_psgi $app, sub {
	      my $cb  = shift;
	      my $res = $cb->(GET "/");
	      is $res->content, "Hello";
	  };

DESCRIPTION

       Plack::Test is a unified interface to test PSGI applications using HTTP::Request and HTTP::Response objects. It also allows you to run PSGI
       applications in various ways. The default backend is "Plack::Test::MockHTTP", but you may also use any Plack::Handler implementation to run
       live HTTP requests against at web server

FUNCTIONS

       test_psgi
	     test_psgi $app, $client;
	     test_psgi app => $app, client => $client;

	   Runs the client test code $client against a PSGI application $app. The client callback gets one argument $cb, a callback that accepts
	   an "HTTP::Request" object and returns an "HTTP::Response" object.

	   Use HTTP::Request::Common to import shortcuts for creating requests for "GET", "POST", "DELETE", and "PUT" operations.

	   For your convenience, the "HTTP::Request" given to the callback automatically uses the HTTP protocol and the localhost (127.0.0.1 by
	   default), so the following code just works:

	     use HTTP::Request::Common;
	     test_psgi $app, sub {
		 my $cb  = shift;
		 my $res = $cb->(GET "/hello");
	     };

	   Note that however, it is not a good idea to pass an arbitrary (i.e. user-input) string to "GET" or even "HTTP::Request->new" by
	   assuming that it always represents a path, because:

	     my $req = GET "//foo/bar";

	   would represent a request for a URL that has no scheme, has a hostname foo and a path /bar, instead of a path //foo/bar which you might
	   actually want.

OPTIONS

       Specify the Plack::Test backend using the environment variable "PLACK_TEST_IMPL" or $Plack::Test::Impl package variable.

       The available values for the backend are:

       MockHTTP
	   (Default) Creates a PSGI env hash out of HTTP::Request object, runs the PSGI application in-process and returns HTTP::Response.

       Server
	   Runs one of Plack::Handler backends ("Standalone" by default) and sends live HTTP requests to test.

       ExternalServer
	   Runs tests against an external server specified in the "PLACK_TEST_EXTERNALSERVER_URI" environment variable instead of spawning the
	   application in a server locally.

       For instance, test your application with the "HTTP::Server::ServerSimple" server backend with:

	 > env PLACK_TEST_IMPL=Server PLACK_SERVER=HTTP::Server::ServerSimple 
	   prove -l t/test.t

AUTHOR

       Tatsuhiko Miyagawa

perl v5.14.2							    2011-09-20							  Plack::Test(3pm)

Plack::Builder(3pm)					User Contributed Perl Documentation				       Plack::Builder(3pm)

NAME

       Plack::Builder - OO and DSL to enable Plack Middlewares

SYNOPSIS

	 # in .psgi
	 use Plack::Builder;

	 my $app = sub { ... };

	 builder {
	     enable "Deflater";
	     enable "Session", store => "File";
	     enable "Debug", panels => [ qw(DBITrace Memory Timer) ];
	     enable "+My::Plack::Middleware";
	     $app;
	 };

	 # use URLMap

	 builder {
	     mount "/foo" => builder {
		 enable "Foo";
		 $app;
	     };

	     mount "/bar" => $app2;
	     mount "http://example.com/" => builder { $app3 };
	 };

	 # using OO interface

	 my $builder = Plack::Builder->new();
	 $builder->add_middleware('Foo', opt => 1);
	 $app = $builder->mount('/app' => $app);
	 $app = $builder->to_app($app);

DESCRIPTION

       Plack::Builder gives you a quick domain specific language (DSL) to wrap your application with Plack::Middleware subclasses. The middleware
       you're trying to use should use Plack::Middleware as a base class to use this DSL, inspired by Rack::Builder.

       Whenever you call "enable" on any middleware, the middleware app is pushed to the stack inside the builder, and then reversed when it
       actually creates a wrapped application handler. "Plack::Middleware::" is added as a prefix by default. So:

	 builder {
	     enable "Foo";
	     enable "Bar", opt => "val";
	     $app;
	 };

       is syntactically equal to:

	 $app = Plack::Middleware::Bar->wrap($app, opt => "val");
	 $app = Plack::Middleware::Foo->wrap($app);

       In other words, you're supposed to "enable" middleware from outer to inner.

INLINE MIDDLEWARE

       Plack::Builder allows you to code middleware inline using a nested code reference.

       If the first argument to "enable" is a code reference, it will be passed an $app and is supposed to return another code reference which is
       PSGI application that consumes $env in runtime. So:

	 builder {
	     enable sub {
		 my $app = shift;
		 sub {
		     my $env = shift;
		     # do preprocessing
		     my $res = $app->($env);
		     # do postprocessing
		     return $res;
		 };
	     };
	     $app;
	 };

       is equal to:

	 my $mw = sub {
	     my $app = shift;
	     sub { my $env = shift; $app->($env) };
	 };

	 $app = $mw->($app);

URLMap support
       Plack::Builder has a native support for Plack::App::URLMap with "mount" method.

	 use Plack::Builder;
	 my $app = builder {
	     mount "/foo" => $app1;
	     mount "/bar" => builder {
		 enable "Foo";
		 $app2;
	     };
	 };

       See Plack::App::URLMap's "map" method to see what they mean. With builder you can't use "map" as a DSL, for the obvious reason :)

       NOTE: Once you use "mount" in your builder code, you have to use "mount" for all the paths, including the root path ("/"). You can't have
       the default app in the last line of "builder" like:

	 my $app = sub {
	     my $env = shift;
	     ...
	 };

	 builder {
	     mount "/foo" => sub { ... };
	     $app; # THIS DOESN'T WORK
	 };

       You'll get warnings saying that your mount configuration will be ignored. Instead you should use "mount "/" => ..." in the last line to set
       the default fallback app.

	 builder {
	     mount "/foo" => sub { ... };
	     mount "/" => $app;
	 }

       Note that the "builder" DSL returns a whole new PSGI application, which means

       o   "builder { ... }" should normally the last statement of a ".psgi" file, because the return value of "builder" is the application that
	   actually is executed.

       o   You can nest your "builder" block, mixed with "mount" (see URLMap support above):

	     builder {
		 mount "/foo" => builder {
		     mount "/bar" => $app;
		 }
	     }

	   will locate the $app under "/foo/bar" since the inner "builder" block puts it under "/bar" and it results a new PSGI application which
	   is located under "/foo" because of the outer "builder" block.

CONDITIONAL MIDDLEWARE SUPPORT

       You can use "enable_if" to conditionally enable middleware based on the runtime environment. See Plack::Middleware::Conditional for
       details.

SEE ALSO

       Plack::Middleware Plack::App::URLMap Plack::Middleware::Conditional

perl v5.14.2							    2012-05-17						       Plack::Builder(3pm)