apache::testrun(3) [osx man page]

Apache::TestRun(3)					User Contributed Perl Documentation					Apache::TestRun(3)

NAME

       Apache::TestRun - Run the test suite

SYNOPSIS

DESCRIPTION

       The "Apache::TestRun" package controls the configuration and running of the test suite.

METHODS

       Several methods are sub-classable, if the default behavior should be changed.

   "bug_report"
       The "bug_report()" method is executed when "t/TEST" was executed with the "-bugreport" option, and "make test" (or "t/TEST") fail. Normally
       this is callback which you can use to tell the user how to deal with the problem, e.g. suggesting to read some document or email some
       details to someone who can take care of it. By default nothing is executed.

       The "-bugreport" option is needed so this feature won't become annoying to developers themselves. It's automatically added to the
       "run_tests" target in Makefile. So if you repeateadly have to test your code, just don't use "make test" but run "t/TEST" directly. Here is
       an example of a custom "t/TEST"

	 My::TestRun->new->run(@ARGV);

	 package My::TestRun;
	 use base 'Apache::TestRun';

	 sub bug_report {
	     my $self = shift;

	     print <<EOI;
	 +--------------------------------------------------------+
	 | Please file a bug report: http://perl.apache.org/bugs/ |
	 +--------------------------------------------------------+
	 EOI
	 }

   "pre_configure"
       The "pre_configure()" method is executed before the configuration for "Apache::Test" is generated. So if you need to adjust the setup
       before httpd.conf and other files are autogenerated, this is the right place to do so.

       For example if you don't want to inherit a LoadModule directive for mod_apreq.so but to make sure that the local version is used, you can
       sub-class "Apache::TestRun" and override this method in t/TEST.PL:

	 package My::TestRun;
	 use base 'Apache::TestRun';
	 use Apache::TestConfig;
	 __PACKAGE__->new->run(@ARGV);

	 sub pre_configure {
	     my $self = shift;
	     # Don't load an installed mod_apreq
	     Apache::TestConfig::autoconfig_skip_module_add('mod_apreq.c');

	     $self->SUPER::pre_configure();
	 }

       Notice that the extension is .c, and not .so.

       Don't forget to run the super class' c<pre_configure()> method.

   "new_test_config"
       META: to be completed

perl v5.16.2							    2011-02-07							Apache::TestRun(3)

Apache::TestMM(3)					User Contributed Perl Documentation					 Apache::TestMM(3)

NAME

       Apache::TestMM - Provide MakeMaker Wrapper Methods

SYNOPSIS

	 require Apache::TestMM;

	 # import MY::test and MY::clean overrides for MM
	 Apache::TestMM->import(qw(test clean));

	 # parse command line args
	 Apache::TestMM::filter_args();

	 # autogenerate the script
	 Apache::TestMM::generate_script('t/TEST');

DESCRIPTION

       "Apache::TestMM" provides wrappers for the "ExtUtils::MakeMaker" craft, making it easier to extend the autogenerated Makefile with
       "Apache::Test".

FUNCTIONS

   "import"
	 use Apache::TestMM qw(test clean);

       or:

	 Apache::TestMM->import(qw(test clean));

       Imports "MY::" overrides for the default "ExtUtils::MakeMaker" test and clean targets, as if you have defined:

	 sub MY::test {...}
	 sub MY::clean {...}

       in Makefile.PL. "Apache::TestMM" does this for you so that these Makefile targets will run the Apache server and the tests for it, and
       clean up after its mess.

   "filter_args"
	 push @ARGV, '-apxs', $apxs_path;
	 Apache::TestMM::filter_args();
	 WriteMakefile(...);

       When "WriteMakefile()" is called it parses @ARGV, hoping to find special options like "PREFIX=/home/stas/perl". "Apache::Test" accepts a
       lot of configuration options of its own. When "Apache::TestMM::filter_args()" is called, it removes any "Apache::Test"-specific options
       from @ARGV and stores them internally, so when "WriteMakefile()" is called they aren't in @ARGV and thus won't be processed by
       "WriteMakefile()".

       The options can be set when Makefile.PL is called:

	 % perl Makefile.PL -apxs /path/to/apxs

       Or you can push them manually to @ARGV from the code:

	 push @ARGV, '-apxs', $apxs_path;

       When:

	 Apache::TestMM::generate_script('t/TEST');

       is called, "Apache::Test"-specific options extracted by "Apache::TestMM::filter_args()" are written to the autogenerated file. In our
       example, the autogenerated t/TEST will include:

	 %Apache::TestConfig::Argv = qw(apxs /path/to/apxs);

       which is going to be used by the "Apache::Test" runtime.

       The other frequently used options are: "-httpd", telling where to find the httpd (usually when the "-apxs" option is not used),
       "-libmodperl" to use a specific mod_perl shared object (if your mod_perl is built as DSO), "-maxclients" to change the default number of
       the configured "MaxClients" directive, "-port" to start the server on a specific port, etc. To get the complete list of available
       configuration options and their purpose and syntax, run:

	 % perl -MApache::TestConfig -le 'Apache::TestConfig::usage()'

       You may wish to document some of these in your application's README file, especially the "-apxs" and "-httpd" options.

   "generate_script"
	 Apache::TestMM::generate_script('t/TEST');

       "generate_script()" accepts the name of the script to generate and will look for a template with the same name and suffix .PL. So in our
       example it'll look for t/TEST.PL. The autogenerated script t/TEST will include the contents of t/TEST.PL, and special directives, including
       any configuration options passed via "filter_args()" called from Makefile.PL, special fixup code, etc.

perl v5.18.2							    2015-06-18							 Apache::TestMM(3)